#!/usr/bin/perl
# $FreeWRT$
#-
# This file is part of the FreeWRT project. FreeWRT is copyrighted
# material, please see the LICENCE file in the top-level directory
# or at http://www.freewrt.org/licence for details.

use strict;
use warnings;

my $target = shift @ARGV;
my $filename = shift @ARGV;
my $md5sum = shift @ARGV;
my @mirrors;

my $ok;

@ARGV > 0 or die "Syntax: $0 <target dir> <filename> <md5sum> <mirror> [<mirror> ...]\n";

sub download
{
	my $mirror = shift;
	
	open WGET, "wget -t1 --timeout=20 -O- \"$mirror/$filename\" |" or die "Cannot launch wget.\n";
	open MD5SUM, "| md5sum > \"$target/$filename.md5sum\"" or die "Cannot launch md5sum.\n";
	open OUTPUT, "> $target/$filename.dl" or die "Cannot create file $target/$filename.dl: $!\n";
	my $buffer;
	while (read WGET, $buffer, 1048576) {
		print MD5SUM $buffer;
		print OUTPUT $buffer;
	}
	close MD5SUM;
	close WGET;
	close OUTPUT;
	
	if (($? >> 8) != 0 ) {
		print STDERR "Download failed.\n";
		cleanup();
		return;
	}
	
	my $sum = `cat "$target/$filename.md5sum"`;
	$sum =~ /^(\w+)\s+/ or die "Could not generate md5sum\n";
	$sum = $1;
	
	if ($md5sum ne 'NO') {
		if ($sum ne $md5sum) {
			print STDERR "MD5 sum of the downloaded file does not match - deleting download.\n";
			cleanup();
			return;
		}
	}
	
	unlink "$target/$filename";
	system("mv \"$target/$filename.dl\" \"$target/$filename\"");
	cleanup();
}

sub cleanup
{
	unlink "$target/$filename.dl";
	unlink "$target/$filename.md5sum";
}

foreach my $mirror (@ARGV) {
	if ($mirror =~ /^\@SF\/(.+)$/) {
		my $sfpath = $1;
		push @mirrors, "http://easynews.dl.sourceforge.net/sourceforge/$sfpath";
		push @mirrors, "http://puzzle.dl.sourceforge.net/sourceforge/$sfpath";
		push @mirrors, "http://optusnet.dl.sourceforge.net/sourceforge/$sfpath";
		push @mirrors, "http://heanet.dl.sourceforge.net/sourceforge/$sfpath";
		push @mirrors, "http://jaist.dl.sourceforge.net/sourceforge/$sfpath";
		push @mirrors, "http://nchc.dl.sourceforge.net/sourceforge/$sfpath";
		push @mirrors, "http://switch.dl.sourceforge.net/sourceforge/$sfpath";
		push @mirrors, "http://kent.dl.sourceforge.net/sourceforge/$sfpath";
		push @mirrors, "http://internap.dl.sourceforge.net/sourceforge/$sfpath";
		push @mirrors, "http://mesh.dl.sourceforge.net/sourceforge/$sfpath";
		push @mirrors, "http://ovh.dl.sourceforge.net/sourceforge/$sfpath";
		push @mirrors, "http://surfnet.dl.sourceforge.net/sourceforge/$sfpath";
		push @mirrors, "http://ufpr.dl.sourceforge.net/sourceforge/$sfpath";
		push @mirrors, "http://dl.sourceforge.net/sourceforge/$sfpath";
	} elsif ($mirror =~ /^\@GNU\/(.+)$/) {
		my $gnupath = $1;
		push @mirrors, "ftp://ftp.gnu.org/gnu/$gnupath";
		push @mirrors, "ftp://ftp.belnet.be/mirror/ftp.gnu.org/gnu/$gnupath";
		push @mirrors, "ftp://ftp.mirror.nl/pub/mirror/gnu/$gnupath";
		push @mirrors, "http://mirror.switch.ch/ftp/mirror/gnu/$gnupath";
		push @mirrors, "ftp://ftp.uu.net/archive/systems/gnu/$gnupath";
		push @mirrors, "ftp://ftp.eu.uu.net/pub/gnu/$gnupath";
		push @mirrors, "ftp://ftp.leo.org/pub/comp/os/unix/gnu/$gnupath";
		push @mirrors, "ftp://ftp.digex.net/pub/gnu/$gnupath";
	} else {
		push @mirrors, $mirror;
	}
}

push @mirrors, 'http://www.freewrt.org/distfiles/';

while (!$ok) {
	my $mirror = shift @mirrors;
	$mirror or die "No more mirrors to try - giving up.\n";
	
	download($mirror);
	-f "$target/$filename" and $ok = 1;
}

$SIG{INT} = \&cleanup;